~aleteoryx/muditaos

muditaos/cmake/modules/AutoModuleOption.cmake -rw-r--r-- 1.7 KiB
a405cad6 — Aleteoryx trim readme 6 days ago 
                                                                                
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Copyright (c) 2017-2022, Mudita Sp. z.o.o. All rights reserved.
# For licensing, see https://github.com/mudita/MuditaOS/LICENSE.md

# function to add:
# - module library to compilation
# - module definition to compilation
# - cmake option enabled by default
# this way we can enable/disable apps or services in cmake
function(add_module_options)

    cmake_parse_arguments( _ARG
                           ""
                           "OPTION_PREFIX;CATALOG_PREFIX;DEFINES_LIST_NAME"
                           "IN_MODULE_NAMES"
                            ${ARGN}
                           )

    message("configurables added: ${_ARG_IN_MODULE_NAMES}")

    list(SORT _ARG_IN_MODULE_NAMES)
    foreach(app IN LISTS _ARG_IN_MODULE_NAMES)

        message("-> configuring option and define for: ${app}")

        string(TOUPPER ${app} app_upper)
        string(REPLACE "-" "_" app_macro_name ${app_upper})

        #add option for each element from the IN_MODULE_NAMES
        if (NOT DEFINED ENABLE_${_ARG_OPTION_PREFIX}_${app_macro_name})
            message("    adding option: ${app}")
            option(ENABLE_${_ARG_OPTION_PREFIX}_${app_macro_name} "Enable ${_ARG_CATALOG_PREFIX} ${app}" ON)
        endif()

        # add #define for each application to list
        if(ENABLE_${_ARG_OPTION_PREFIX}_${app_macro_name})
            message("    adding definition for: ${app}")
            add_subdirectory(${_ARG_CATALOG_PREFIX}-${app})
            list(APPEND _TMP "ENABLE_${_ARG_OPTION_PREFIX}_${app_macro_name}")
        endif()
    endforeach()


    set(${_ARG_DEFINES_LIST_NAME} ${_TMP} PARENT_SCOPE)
    message("defines for ${_ARG_DEFINES_LIST_NAME} set to: ${_TMP}")

endfunction()